formülleri yeni sayfada listeler Hazır Excel Makroları (VBA) | Excel Programları

Makroyu Kopyala

'Excel Makro (VBA) online eğitimleri için: https://www.excelsizeyeter.com/excelsizeyeter.com/udemy_giris.php adresine tıklayınız. Bir eğitim alana bir eğitim bedavadır. İkinci eğitim olarak Excel, Excel pratik çözümler, finans eğitimleri vb. alabilirsiniz. 
 
 Option Explicit

Public Sub ListFormulasInWorkbook()
        ' by J.E. McGimpsey
        ' revised 04 July 2003 by Tom Ogilvy to add
        '   sheets when reaching ROWLIM formulas
        Const SHEETNAME As String = "Formulas in *"
        Const ALLFORMULAS As Integer = _
            xlNumbers + xlTextValues + xlLogical + xlErrors
        Const ROWLIM As Long = 65500
        Dim formulaSht As Worksheet
        Dim destRng As Range
        Dim cell As Range
        Dim wkSht As Worksheet
        Dim formulaRng As Range
        Dim shCnt As Long
        Dim oldScreenUpdating As Boolean
        
        With Application
            oldScreenUpdating = .ScreenUpdating
            .ScreenUpdating = False
        End With
        shCnt = 0
        ListFormulasAddSheet formulaSht, shCnt
            ' list formulas on each sheet
            Set destRng = formulaSht.Range("A4")
            For Each wkSht In ActiveWorkbook.Worksheets
                If Not wkSht.Name Like SHEETNAME Then
                    Application.StatusBar = wkSht.Name
                    destRng.Value = wkSht.Name
                    Set destRng = destRng.Offset(1, 0)
                    On Error Resume Next
                    Set formulaRng = wkSht.Cells.SpecialCells( _
                            xlCellTypeFormulas, ALLFORMULAS)
                    On Error GoTo 0
                    If formulaRng Is Nothing Then
                        destRng.Offset(0, 1).Value = "None"
                        Set destRng = destRng.Offset(1, 0)
                    Else
                        For Each cell In formulaRng
                            With destRng
                                .Offset(0, 1) = cell.Address(0, 0)
                                .Offset(0, 2) = "'" & cell.Formula
                                .Offset(0, 3) = cell.Value
                            End With
                            Set destRng = destRng.Offset(1, 0)
                            If destRng.row > ROWLIM Then
                              ListFormulasAddSheet formulaSht, shCnt
                              Set destRng = formulaSht.Range("A5")
                              destRng.Offset(-1, 0).Value = wkSht.Name
                            End If
                        Next cell
                        Set formulaRng = Nothing
                    End If
                    With destRng.Resize(1, 4).Borders(xlEdgeBottom)
                        .LineStyle = xlContinuous
                        .Weight = xlThin
                        .ColorIndex = 5
                    End With
                    Set destRng = destRng.Offset(1, 0)
                    If destRng.row > ROWLIM Then
                        ListFormulasAddSheet formulaSht, shCnt
                        Set destRng = formulaSht.Range("A5")
                        destRng.Offset(-1, 0).Value = wkSht.Name
                    End If
                End If
            Next wkSht
        With Application
            .StatusBar = False
            .ScreenUpdating = oldScreenUpdating
        End With
    End Sub

Private Sub ListFormulasAddSheet( _
                formulaSht As Worksheet, shtCnt As Long)
        Const SHEETNAME As String = "Formulas in "
        Const SHEETTITLE As String = "Formulas in $ as of "
        Const DATEFORMAT As String = "dd MMM yyyy hh:mm"
        Dim shtName As String

With ActiveWorkbook
            ' Delete existing sheet and create new one
            shtCnt = shtCnt + 1
            shtName = Left(SHEETNAME & .Name, 28)
            If shtCnt > 1 Then _
                shtName = shtName & "_" & shtCnt
             On Error Resume Next
            Application.DisplayAlerts = False
            .Worksheets(shtName).Delete
            Application.DisplayAlerts = True
            On Error GoTo 0
            Set formulaSht = .Worksheets.Add( _
                    after:=Sheets(Sheets.Count))
        End With

With formulaSht
            ' Format headers
            .Name = shtName
            .Columns(1).ColumnWidth = 15
            .Columns(2).ColumnWidth = 8
            .Columns(3).ColumnWidth = 60
            .Columns(4).ColumnWidth = 40
            With .Range("C:D")
                .Font.Size = 9
                .HorizontalAlignment = xlLeft
                .EntireColumn.WrapText = True
            End With
            With .Range("A1")
                .Value = Application.Substitute(SHEETTITLE, "$", _
                        ActiveWorkbook.Name) & Format(Now, DATEFORMAT)
                With .Font
                    .Bold = True
                    .ColorIndex = 5
                    .Size = 14
                End With
            End With
            With .Range("A3").Resize(1, 4)
                .Value = Array("Sheet", "Address", "Formula", "Value")
                With .Font
                    .ColorIndex = 13
                    .Bold = True
                    .Size = 12
                End With
                .HorizontalAlignment = xlCenter
                With .Borders(xlEdgeBottom)
                    .LineStyle = xlDouble
                    .Weight = xlThick
                    .ColorIndex = 5
                End With
            End With
        End With
    End Sub

Benzer Sonuçlar
No	Makro Adı
1	formülleri yeni sayfada listeler
2	aktif sayfadaki formülleri bulur yeni sayfaya listeler
3	excelde kendi eklenti ve fonksiyonlarınızı oluşturun
4	kitapta ne kadar formül varsa ayrıntılı olarak belirtir (yeni sayfada)
5	hücrede bir sonraki ayın gün sayısı kadar gün ilave etme
6	menü çubuğunun silinmesi ve özel bir menünün oluşturulması
7	hücredeki renge göre filtreleme
8	hücredeki yazi karakterinin rengine göre filtreleme
9	sayfadan adres alıp sütun genişliği ayarlama
10	forma otomatik resim getirme
11	sayfadaki formüllü hücrelerin formüllerini açıklama olarak ekleme ve silme
12	sayfada formülleri silmeyi engelleme (delete tuş iptali)
13	kitapta ne kadar refers varsa ayrıntılı olarak belirtir (yeni sayfada)
14	eski formülleri geri getirme (förmül yenileme)
15	tek hücrede yer alan "ad soyad" bilgisini ayrı hücrelere alma
16	başka kitaptan combobox a veri alma
17	sayfada formüllü hücreleri records sayfasına ayrıntılı kaydeder
18	sayfadan var ise sayfaadi'ni seçip sayfa üzerinde işleme devam edecek yok ise eğer sayfaadi altında yeni çalışma sayfası açacak
19	makroda bul ve kopyala yapıştır
20	sayfada formüller silinmesin (diğerlerinin silinmesine izin verir)

Benzer Sonuçlar

Makro Adı

formülleri yeni sayfada listeler

aktif sayfadaki formülleri bulur yeni sayfaya listeler

excelde kendi eklenti ve fonksiyonlarınızı oluşturun

kitapta ne kadar formül varsa ayrıntılı olarak belirtir (yeni sayfada)

hücrede bir sonraki ayın gün sayısı kadar gün ilave etme

menü çubuğunun silinmesi ve özel bir menünün oluşturulması

hücredeki renge göre filtreleme

hücredeki yazi karakterinin rengine göre filtreleme

sayfadan adres alıp sütun genişliği ayarlama

forma otomatik resim getirme